***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 26, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX584C3V9-AU A K 
.param
+vc0 = 1.046e-10		vc1 = 8.016e-10		vc2 = 1.100			vc3 = 2.306e-8		vc4 = 8.996
+tc1 = 1.061e-2		tc2 = 1.021e-2		tc3 = 5.101e-3		tc4 = 2.021e-3
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 7.368e-15		   n = 1.109		  rs = 2.987e-1
+ibv = 0.2e-3			 nbv = 4.5			  bv = 3.9
+ikf = 2.515e-1
***** capacitance parameter *****
+cjo = 1.653e-10		   m = 3.715e-1		  vj = 8.263e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.113		 xti = 3
+trs1 = 5.056e-4		trs2 = 7.203e-6		tikf = 3.0e-3
+tbv1 = -1.561e-4		tbv2 = 2.066e-6	
.ends BZX584C3V9-AU
*$
